<%
' Comersus Shopping Cart 
' Comersus Open Technologies
' United States 
' Software License can be found at License.txt
' http://www.comersus.com  
' Details: get products marked as showInHome
%>

<!--#include file="../includes/settings.asp"--> 
<!--#include file="../includes/getSettingKey.asp"--> 
<!--#include file="../includes/sessionFunctions.asp"--> 
<!--#include file="../includes/screenMessages.asp"-->
<!--#include file="../includes/databaseFunctions.asp"--> 
<!--#include file="../includes/currencyFormat.asp"--> 
<!--#include file="../includes/itemFunctions.asp"--> 
<!--#include file="../includes/miscFunctions.asp"--> 
<!--#include file="../includes/dateFunctions.asp"--> 

<% 

on error resume next 

dim connTemp, rsTemp, rsTemp3, pItemsShown, pMaxPopularity, arrCounter, pIdCustomer, pIdCustomerType, howManyHome, mySQL, pDefaultLanguage, pStoreFrontDemoMode, pCurrencySign, pDecimalSign, pMoneyDontRound, pCompany, pCompanyLogo, pHeaderKeywords, pAuctions, pListBestSellers, pNewsLetter, pPriceList, pStoreNews, pOneStepCheckout, pAffiliatesStoreFront, pShowStockView, pIdProductVip, pLastChanceListing, pAllowNewCustomer, pListProductsByLetter, pRunInstallationWizard, pIdProduct, pDescription, pDetails, pDetailsVip, pImageUrlVip, pLanguage, pCustomerName, pHeaderCartItems, pHeaderCartSubtotal, pItemCounter, f, h

call saveCookie()

' get settings 

pStoreFrontDemoMode 	= getSettingKey("pStoreFrontDemoMode")
pCurrencySign	 	= getSettingKey("pCurrencySign")
pDecimalSign	 	= getSettingKey("pDecimalSign")
pMoneyDontRound	 	= getSettingKey("pMoneyDontRound")
pCompany	 	= getSettingKey("pCompany")
pCompanySlogan 		= getSettingKey("pCompanySlogan")
pAboutUsLink 		= getSettingKey("pAboutUsLink")
pStoreLocation		= getSettingKey("pStoreLocation")

pHeaderKeywords		= getSettingKey("pHeaderKeywords")
pDateSwitch		= getSettingKey("pDateSwitch")
pDateFormat		= getSettingKey("pDateFormat")

pSuppliersList		= getSettingKey("pSuppliersList")
pAuctions		= getSettingKey("pAuctions")
pAffiliatesStoreFront   = getSettingKey("pAffiliatesStoreFront")
pRssFeedServer		= getSettingKey("pRssFeedServer")
pNewsLetter 		= getSettingKey("pNewsLetter")

pShowStockView		= getSettingKey("pShowStockView")
pAllowNewCustomer	= getSettingKey("pAllowNewCustomer")
pRunInstallationWizard 	= getSettingKey("pRunInstallationWizard")
pItemsShown 		= Cint(getSettingKey("pItemsShown"))
pShowNews		= getSettingKey("pShowNews")
pShowAddedToday		= getSettingKey("pShowAddedToday")

if pRunInstallationWizard="-1" then 
 response.redirect "../backofficeLite/comersus_backoffice_install0.asp"
end if

pMaxPopularity 	= 0
arrCounter	= 0
pTodayCount	= 0
pIdCustomer     = getSessionVariable("idCustomer",0)
pIdCustomerType = getSessionVariable("idCustomerType",1)

' get how many products are marked as showInHome

mySQL="SELECT COUNT(idProduct) AS howManyHome FROM products WHERE showInHome=-1 AND active=-1 AND listHidden=0 AND idStore=" &pIdStore
   
call getFromDatabase (mySql, rsTemp3, "dynamic_index")

if rsTemp3.eof then
 howManyHome=0
else
 howManyHome=rstemp3("howManyHome")
end if

if Cint(howManyHome)<Cint(pItemsShown) then 
 ' redirect to categories listing since there are no enough products to show in home
 response.redirect "comersus_listCategories.asp"
end if

' get products marked as showInHome

mySQL="SELECT idProduct, description, imageUrl, visits, map FROM products WHERE showInHome=-1 AND listHidden=0 AND active=-1 AND idStore=" &pIdStore

call getFromDatabase (mySql, rsTemp3, "dynamic_index")

' define the array to store products (2 columns)
reDim arrProducts(pItemsShown,9)

' load the array only with spots available 

do while (not rstemp3.eof) and arrCounter<(pItemsShown)  
 
 ' load product array 
 arrProducts(arrCounter,0)= rstemp3("idProduct")
 arrProducts(arrCounter,1)= rstemp3("description") 
 arrProducts(arrCounter,4)= rstemp3("imageUrl")
 arrProducts(arrCounter,5)= getStock(rstemp3("idProduct"))
 arrProducts(arrCounter,7)= rstemp3("visits")
 arrProducts(arrCounter,8)= rstemp3("map")
 
 arrCounter = arrCounter+1
 
 rstemp3.moveNext
loop 

' calculate maximum visits
pMaxPopularity=getMax(arrProducts)

%>
<!--#include file="header.asp"-->      
<table border=0 cellpadding=0 cellspacing=0>      
<%

pColNumber=1

for f=0 to pItemsShown-1
%> 

   <%if pColNumber=1 then%>
    <tr><td width="50%" height="50">
   <%end if%>     

     <%if arrProducts(f,4)<>"" then%>
       <a href="comersus_viewItem.asp?idProduct=<%=arrProducts(f,0)%>"><img align=left alt="<%=arrProducts(f,1)%>" border=0 src="catalog/<%=arrProducts(f,4)%>" vspace=3></a> 
     <%else%>
       <img src='catalog/imageNA.gif' alt="<%=getMsg(5,"Not availab")%>">              
     <%end if%>
            
     <b><%=arrProducts(f,1)%></b>          
     
     <%if pShowStockView="-1" then%>
      <br><%=getMsg(3,"Stock")%>: <%=arrProducts(f,5)%>
     <%end if%>
     
     <br> <%=getMsg(4,"Pop")%> &nbsp;<%=arrProducts(f,7)%> <img border=0 src="images/<%=getPopularity(arrProducts(f,7),pMaxPopularity)%>popular.gif"> 
     <br><a href="comersus_viewItem.asp?idProduct=<%=arrProducts(f,0)%>"><%=getMsg(1,"More")%></a>     
     
     <br><%=getMsg(2,"Price")%> &nbsp;
     <%if arrProducts(f,8) = "-1" Then%>
     	<i><%=getMsg(745,"add to cart to find out")%></i> 	
     <%else%>
     	<%=pCurrencySign & money(getPrice(arrProducts(f,0), pIdCustomerType, pIdCustomer))%>     
     <%end if%>
           
      <form method=post action="comersus_addItem.asp">       
       <input alt="Add to Cart" border=0 src="images/addCart.gif" type=image name="add">
       <input type=hidden name=idProduct value=<%=arrProducts(f,0)%>>    
       <input type=hidden name=quantity value="1">    
      </form>

  <%if pColNumber=1 then%>
   </td><td width="50%" height="50">
   <%pColNumber=2%>
  <%else%> 
   </td></tr>
   <%pColNumber=1%>
  <%end if%>     
        
<%next%>   

<%if pShowAddedToday="-1" then
 
 mySQL="SELECT idProduct, description FROM products WHERE dateAdded='" &Date()& "' AND idStore="& pIdStore& " AND listHidden=0 AND active=-1 and isBundleMain=0 ORDER BY idProduct DESC"
 
 call getFromDatabase(mySql, rstemp,"index")
 
  if not rsTemp.eof then 
    pIdProduct1		=rstemp("idProduct")
    pDescription1	=rstemp("description")
    pTodayCount	=pTodayCount+1
 end if

 if not rsTemp.eof then rstemp.movenext

 if not rsTemp.eof then 
    pIdProduct2		=rstemp("idProduct")
    pDescription2	=rstemp("description")
    pTodayCount	=pTodayCount+1
 end if
 
end if%>

<%if pShowAddedToday="-1" and pTodayCount>1 then%>
<tr>
<td colspan=2>&nbsp;</td></tr>
<tr>
<td colspan=2>

<table border="0" cellpadding="0" cellspacing="0" width="95%" align="center" height="25" background="images/fon_bar01.gif">
  <tr> 
    <td> 
      <table border="0" cellpadding="0" cellspacing="0" background="" bgcolor="#FFFFFF">
        <tr> 
          <td><img src="images/e04.gif" width="21" height="21" alt="" border="0"></td>
          <td>
            <p class="bar01" style="color: #3366CC; font-size: 18px;"><%=getMsg(724,"added today")%> &nbsp;</p>
          </td>
        </tr>
      </table>
    </td>
  </tr>
</table>

<table border="0" cellpadding="0" cellspacing="0" align="center">
  <tr> 
    <td width="275"> 
      <p class="left"><img src="images/dot_b.gif" width="5" height="5" alt="" border="0" align="absmiddle">&nbsp;&nbsp;<b><%=pDescription1%></b></p>
       <p class="left"><%=getMsg(2,"Price")%> &nbsp;<%=pCurrencySign & money(getPrice(pIdProduct1, pIdCustomerType, pIdCustomer))%></p>
      <p class="left"><a href="comersus_viewItem.asp?idProduct=<%=pIdProduct1%>"><%=getMsg(725,"More...")%></a></p>
    </td>
    <td bgcolor="#979797"><img src="images/px1.gif" width="1" height="1" alt="" border="0"></td>
    <td width="275"> 
      <p class="left"><img src="images/dot_b.gif" width="5" height="5" alt="" border="0" align="absmiddle">&nbsp;&nbsp;<b><%=pDescription2%></b></p>
      <p class="left"><%=getMsg(2,"Price")%> &nbsp;<%=pCurrencySign & money(getPrice(pIdProduct2, pIdCustomerType, pIdCustomer))%></p>
      <p class="left"><a href="comersus_viewItem.asp?idProduct=<%=pIdProduct2%>"><%=getMsg(725,"More...")%></a></p>
    </td>
  </tr>
</table>

</td></tr>
<%end if%>
</table>
<!--#include file="footer.asp"--> 
<%call closeDb()%>